# KPIビジュアルの値について

**URL:** <https://community.amazonquick.com/t/kpi/29701>\
**Category:** 日本語で質問 | Q&A\
**Tags:** Japanese, Business-Intelligence-Engineer\
**Created:** [May 13, 2024, 8:31am UTC](https://community.amazonquick.com/t/kpi/29701 "2024-05-13T08:31:53Z")\
**Posts on this page:** 3\
**Page:** 1

<div class="post-metadata">

**Author:** ![naka](https://avatars.discourse-cdn.com/v4/letter/n/7c8e57/32.png) [@naka](https://community.amazonquick.com/u/naka)\
**Post date:** [May 13, 2024, 8:31am UTC](https://community.amazonquick.com/t/kpi/29701/1 "2024-05-13T08:31:53Z")

</div>

|日付 | 区分 | 実績 | 見通 | 予算|  
|2024/05/10 | 予算 | 0 | 0 | 123,456|  
|2024/05/10 | 実績 | 132,465 | 0 | 0|  
|2024/05/10 | 見通 | 0 | 98,765 | 0|  
|2024/05/11 | 予算 | 0 | 0 | 234,567|  
|2024/05/11 | 実績 | 243,567 | 0 | 0|  
|2024/05/11 | 見通 | 0 | 187,654 | 0|  
|2024/05/12 | 予算 | 0 | 0 | 345,678|  
|2024/05/12 | 実績 | 354,687 | 0 | 0|  
|2024/05/12 | 見通 | 0 | 276,542 | 0|  
|2024/05/13 | 予算 | 0 | 0 | 134,679|  
|2024/05/13 | 見通 | 0 | 107,743 | 0|  
|2024/05/14 | 予算 | 0 | 0 | 246,813|  
|2024/05/14 | 見通 | 0 | 197,450 | 0|  
|2024/05/15 | 予算 | 0 | 0 | 356,819|  
|2024/05/15 | 見通 | 0 | 285,455 | 0|  
|2024/05/16 | 予算 | 0 | 0 | 147,258|  
|2024/05/16 | 見通 | 0 | 117,806 | 0|  
|2024/05/17 | 予算 | 0 | 0 | 258,369|  
|2024/05/17 | 見通 | 0 | 206,695 | 0|  
|2024/05/18 | 予算 | 0 | 0 | 369,147|  
|2024/05/18 | 見通 | 0 | 295,318 | 0|  
|2024/05/19 | 予算 | 0 | 0 | 145,836|  
|2024/05/19 | 見通 | 0 | 116,669 | 0|  
|2024/05/20 | 予算 | 0 | 0 | 472,569|  
|2024/05/20 | 見通 | 0 | 378,055 | 0|  
|2024/05/21 | 予算 | 0 | 0 | 251,436|  
|2024/05/22 | 予算 | 0 | 0 | 362,514|  
|2024/05/23 | 予算 | 0 | 0 | 172,839|  
|2024/05/24 | 予算 | 0 | 0 | 283,917|  
|2024/05/25 | 予算 | 0 | 0 | 391,728|

上記データセットから、下記の計算フィールドを作成して日毎の着地予想を求めて、その値をビジュアルのKPIに表示させました。

計算フィールドA:sum(見通,[日付])  
計算フィールドB:sum(予算,[日付])  
計算フィールドC:ifelse(sum(dateDiff(now(),日付))\>=0,ifelse(sum({計算フィールドA})\>0,sum({計算フィールドA}),sum({計算フィールドB})),sum(実績))

その際に、KPIに表示される値が想定と異なる値が表示されました。  
（想定では下記画像内の赤枠部が表示される想定でした。）  
ビジュアルのテーブル上では、値\>合計\>デフォルトを値\>合計\>合計と変更する事で想定していた値を表示することが出来ました。

 ![image](https://d1wl4jav5dp96l.cloudfront.net/original/3X/9/e/9ed7e3a248f86f1597b06c6c962601669da3cddd.png)

結果として、ビジュアルのKPIで上記画像内の赤枠部の値を表示することは出来ないのでしょうか？

何か別の手順などありましたらご教示いただければ幸いです。

求めたい値は下記の通りです。  
過去日付であれば実績の値、  
本日以降の日付であれば、区分="見通"のデータがあれば見通の値、なければ予算の値

---

<div class="post-metadata">

**Author:** ![Masahito](https://d2orw1595917va.cloudfront.net/user_avatar/community.amazonquick.com/masahito/32/25379_2.png) [@Masahito](https://community.amazonquick.com/u/Masahito)\
**Post date:** [May 13, 2024, 2:23pm UTC](https://community.amazonquick.com/t/kpi/29701/2 "2024-05-13T14:23:22Z")

</div>

以下の２ステップでご期待通りの結果になるかご確認頂けますでしょうか？

１）計算フィールドAにsumOver関数を適用  
`sumOver(見通,[日付], PRE_AGG)`

＜ご参考＞

> **[Amazon でのレベル対応計算の使用 QuickSight - Amazon QuickSight](https://docs.aws.amazon.com/ja_jp/quicksight/latest/user/level-aware-calculations.html)**
>
> Amazon QuickSight 分析でレベル対応の計算を使用して、ウィンドウまたは集計関数を評価の順序に挿入します。

２）計算フィールドC’を以下の通り定義

```auto
ifelse(
    区分 = '実績',
    実績, /* 区分が実績のレコードは{実績}の値 */
    ifelse(
        dateDiff(now(),日付)<0,
        0, /* 区分が実績以外、かつ、過去日付のレコードは0 */
        ifelse(
            区分 = '見通',
            見通, /* 区分が見通、かつ、未来日付のレコードは{見通}の値 */
            ifelse( /* 区分が予算（実績でも見通でもない）のレコード*/
                NOT(計算フィールドA = 0),
                0, /* 計算フィールAが0でない、すなわち同日付に区分="見通"のデータがある場合は0 */
                予算
            )
        )
    )
)

```

**結果イメージ**  
A）テーブル  
※ディメンションとして「日付」「区分」両方を指定した状態でビジュアル（テーブル）を確認頂くと上記計算式の意図が理解しやすいかと思います。

 ![image](https://d1wl4jav5dp96l.cloudfront.net/original/3X/0/b/0b1a6eb6467a02718df07ca6988323d2e7734a27.png)

B）KPI

 ![image](https://d1wl4jav5dp96l.cloudfront.net/original/3X/4/1/4186785308c5b764436f1533869e7a6e24e53c96.png)

---

<div class="post-metadata">

**Author:** ![naka](https://avatars.discourse-cdn.com/v4/letter/n/7c8e57/32.png) [@naka](https://community.amazonquick.com/u/naka)\
**Post date:** [May 14, 2024, 5:00am UTC](https://community.amazonquick.com/t/kpi/29701/3 "2024-05-14T05:00:29Z")

</div>

ご回答ありがとうございます。  
頂いた手順にて、期待通りの結果を得ることが出来ました。